# SPDX-FileCopyrightText: 2026 Eike Hein <hein@kde.org>
# SPDX-License-Identifier: BSD-2-Clause

add_library(kwi-core STATIC
    TerminalSession.cpp
    SessionModel.cpp
    RunningCommandCheck.cpp
    DesktopIntegration.cpp
    settings/TerminalSettings.cpp settings/SettingsConstraints_p.h
    settings/LaunchSettings.cpp
    settings/TerminalPresets.cpp
    settings/PresetEditor.cpp
    settings/TerminalPaletteModel.cpp
)
kconfig_add_kcfg_files(kwi-core GENERATE_MOC settings/TerminalPreferences.kcfgc)
install(FILES settings/TerminalPreferences.kcfg DESTINATION ${KDE_INSTALL_KCFGDIR})
target_include_directories(kwi-core PUBLIC "${CMAKE_CURRENT_SOURCE_DIR}" "${CMAKE_CURRENT_BINARY_DIR}")
target_link_libraries(kwi-core
    PUBLIC Qt6::Core Qt6::Gui Qt6::QmlIntegration KF6::ConfigCore KF6::ConfigGui
        KF6::I18n kwi-terminal
    PRIVATE KF6::CoreAddons KF6::KIOGui KF6::Notifications KF6::WindowSystem)
target_compile_definitions(kwi-core PRIVATE TRANSLATION_DOMAIN="kwi")

set_target_properties(kwi-core PROPERTIES POSITION_INDEPENDENT_CODE ON)

add_library(kwi-ui STATIC)

set(kwi_qml_files
    declarative/TerminalPane.qml
    declarative/TerminalSearchBar.qml
    declarative/TerminalSearchField.qml
    declarative/+org.kde.union/TerminalSearchField.qml
    declarative/components/PromptDialogFooter.qml
    declarative/components/WebShortcutMenu.qml
    declarative/settings/AppearanceSettings.qml
    declarative/settings/BehaviorSettings.qml
    declarative/settings/ColorSchemeEditor.qml
    declarative/settings/PresetsSettings.qml
    declarative/settings/SettingsPage.qml
    declarative/settings/TerminalSettings.qml)

set(kwi_ui_sources
    ui/TextFormatting.cpp ui/TextFormatting.h
    settings/WindowColorSchemes.cpp settings/WindowColorSchemes.h
    ui/WebShortcutModel.cpp ui/WebShortcutModel.h)

set_source_files_properties(declarative/+org.kde.union/TerminalSearchField.qml
    PROPERTIES QT_QML_SKIP_QMLDIR_ENTRY TRUE)

if(BUILD_APP)
    list(APPEND kwi_qml_files
        declarative/ActionDefinitions.qml
        declarative/Main.qml
        declarative/TabCloseButton.qml
        declarative/TerminalTabButton.qml
        declarative/TerminalTabs.qml
        declarative/+org.kde.desktop/TabCloseButton.qml
        declarative/+org.kde.union/TabCloseButton.qml
        declarative/components/NativeMenu.qml
        declarative/components/NativeMenuItem.qml
        declarative/settings/KeyboardSettings.qml)
    list(APPEND kwi_ui_sources
        WindowManager.h WindowManager.cpp
        ui/NativeTabClose.cpp ui/NativeTabClose.h)
    set_source_files_properties(
        declarative/+org.kde.desktop/TabCloseButton.qml
        declarative/+org.kde.union/TabCloseButton.qml
        PROPERTIES QT_QML_SKIP_QMLDIR_ENTRY TRUE)
endif()

if(BUILD_KPART)
    list(APPEND kwi_qml_files declarative/EmbeddedTerminal.qml)
endif()

foreach(qml_file IN LISTS kwi_qml_files)
    file(RELATIVE_PATH qml_name "${CMAKE_CURRENT_SOURCE_DIR}/declarative" "${CMAKE_CURRENT_SOURCE_DIR}/${qml_file}")
    set_source_files_properties("${qml_file}" PROPERTIES QT_RESOURCE_ALIAS "${qml_name}")
endforeach()

qt_add_qml_module(kwi-ui
    URI org.kde.kwi
    OUTPUT_TARGETS kwi_ui_generated_targets
    RESOURCE_PREFIX "/qt/qml"
    OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/qml/org/kde/kwi"
    CLASS_NAME KwiTerminalPlugin
    QML_FILES ${kwi_qml_files}
    DEPENDENCIES org.kde.kwi.terminal
    SOURCES ${kwi_ui_sources}
)
qt_generate_foreign_qml_types(kwi-core kwi-ui)

set_target_properties(kwi-ui kwi-uiplugin ${kwi_ui_generated_targets}
    PROPERTIES POSITION_INDEPENDENT_CODE ON)

# Link the generated plugin import object into each host.
target_link_libraries(kwi-ui INTERFACE kwi-uiplugin)
target_compile_definitions(kwi-ui PRIVATE TRANSLATION_DOMAIN="kwi")
target_link_libraries(kwi-ui PUBLIC kwi-core Qt6::Quick
    PRIVATE Qt6::QuickControls2 Qt6::Widgets Qt6::DBus KF6::CoreAddons KF6::KIOGui KF6::I18nQml KF6::Kirigami KF6::KirigamiPlatform KF6::WindowSystem KF6::ColorScheme)
target_include_directories(kwi-ui PUBLIC "${CMAKE_CURRENT_SOURCE_DIR}" PRIVATE settings ui)

if(BUILD_APP)
    target_link_libraries(kwi-ui PRIVATE KF6::KirigamiActionCollection)
    qt_add_executable(kwi main.cpp)
    target_link_libraries(kwi PRIVATE kwi-ui Qt6::Widgets KirigamiApp KF6::CoreAddons
        KF6::DBusAddons KF6::I18nQml KF6::Kirigami KF6::WindowSystem)
    target_include_directories(kwi PRIVATE "${PROJECT_BINARY_DIR}")
    install(TARGETS kwi ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
endif()

if(BUILD_KPART)
    add_library(kwi-part-implementation STATIC
        kpart/Part.cpp kpart/PresetProperties.cpp
        ui/TerminalWidget.h ui/TerminalWidget.cpp
        ui/SettingsDialog.h ui/SettingsDialog.cpp)
    target_link_libraries(kwi-part-implementation
        PUBLIC kwi-ui Qt6::QuickWidgets Qt6::DBus KF6::Parts KF6::XmlGui KF6::WidgetsAddons
        PRIVATE KF6::I18nQml KF6::KIOWidgets KF6::ColorScheme KF6::IconThemes KF6::GuiAddons)
    target_compile_definitions(kwi-part-implementation PRIVATE TRANSLATION_DOMAIN="kwi")
    set_target_properties(kwi-part-implementation PROPERTIES POSITION_INDEPENDENT_CODE ON)

    configure_file(kpart/kwipart.json.in kwipart.json @ONLY)

    kcoreaddons_add_plugin(kwipart SOURCES kpart/Plugin.cpp
        INSTALL_NAMESPACE "kf6/parts")
    target_include_directories(kwipart PRIVATE "${CMAKE_CURRENT_BINARY_DIR}")
    target_link_libraries(kwipart PRIVATE kwi-part-implementation)
endif()
